1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
|
///*****************************************************************************
//*
//* Copyright (C) 2012 Ittiam Systems Pvt Ltd, Bangalore
//*
//* Licensed under the Apache License, Version 2.0 (the "License");
//* you may not use this file except in compliance with the License.
//* You may obtain a copy of the License at:
//*
//* http://www.apache.org/licenses/LICENSE-2.0
//*
//* Unless required by applicable law or agreed to in writing, software
//* distributed under the License is distributed on an "AS IS" BASIS,
//* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
//* See the License for the specific language governing permissions and
//* limitations under the License.
//*
//*****************************************************************************/
///**
//*******************************************************************************
//* @file
//* ihevc_intra_pred_luma_mode2_neon.s
//*
//* @brief
//* contains function definitions for intra prediction dc filtering.
//* functions are coded using neon intrinsics and can be compiled using
//* rvct
//*
//* @author
//* yogeswaran rs
//*
//* @par list of functions:
//*
//*
//* @remarks
//* none
//*
//*******************************************************************************
//*/
///**
//*******************************************************************************
//*
//* @brief
//* luma intraprediction filter for dc input
//*
//* @par description:
//*
//* @param[in] pu1_ref
//* uword8 pointer to the source
//*
//* @param[out] pu1_dst
//* uword8 pointer to the destination
//*
//* @param[in] src_strd
//* integer source stride
//*
//* @param[in] dst_strd
//* integer destination stride
//*
//* @param[in] pi1_coeff
//* word8 pointer to the planar coefficients
//*
//* @param[in] nt
//* size of tranform block
//*
//* @param[in] mode
//* type of filtering
//*
//* @returns
//*
//* @remarks
//* none
//*
//*******************************************************************************
//*/
//void ihevc_intra_pred_luma_mode2(uword8 *pu1_ref,
// word32 src_strd,
// uword8 *pu1_dst,
// word32 dst_strd,
// word32 nt,
// word32 mode)
//
//**************variables vs registers*****************************************
//x0 => *pu1_ref
//x1 => src_strd
//x2 => *pu1_dst
//x3 => dst_strd
//stack contents from #40
// nt
// mode
// pi1_coeff
.text
.align 4
.include "ihevc_neon_macros.s"
.globl ihevc_intra_pred_luma_mode2_av8
.type ihevc_intra_pred_luma_mode2_av8, %function
ihevc_intra_pred_luma_mode2_av8:
// stmfd sp!, {x4-x12, x14} //stack stores the values of the arguments
stp x19, x20,[sp,#-16]!
mov x8,#-2
cmp x4,#4
beq mode2_4
add x0,x0,x4,lsl #1
sub x0,x0,#9 //src[1]
add x10,x0,#-1
prologue_cpy_32:
ld1 {v0.8b},[x0],x8
mov x11,x4
ld1 {v1.8b},[x10],x8
mov x6, x2
ld1 {v2.8b},[x0],x8
ld1 {v3.8b},[x10],x8
lsr x1, x4, #3
ld1 {v4.8b},[x0],x8
ld1 {v5.8b},[x10],x8
ld1 {v6.8b},[x0],x8
mul x1, x4, x1
ld1 {v7.8b},[x10],x8
add x7,x6,x3
rev64 v16.8b, v0.8b
rev64 v17.8b, v1.8b
lsl x5, x3, #2
rev64 v18.8b, v2.8b
rev64 v19.8b, v3.8b
add x9,x7,x3
rev64 v20.8b, v4.8b
subs x1,x1,#8
rev64 v21.8b, v5.8b
rev64 v22.8b, v6.8b
rev64 v23.8b, v7.8b
add x14,x9,x3
beq epilogue_mode2
sub x12,x4,#8
kernel_mode2:
st1 {v16.8b},[x6],x5
st1 {v17.8b},[x7],x5
subs x11,x11,#8
st1 {v18.8b},[x9],x5
add x20,x2,#8
csel x2, x20, x2,gt
st1 {v19.8b},[x14],x5
st1 {v20.8b},[x6],x5
csel x11, x4, x11,le
st1 {v21.8b},[x7],x5
st1 {v22.8b},[x9],x5
add x20, x2, x3, lsl #2
csel x2, x20, x2,le
st1 {v23.8b},[x14],x5
ld1 {v0.8b},[x0],x8
sub x14,x4,#8
ld1 {v1.8b},[x10],x8
ld1 {v2.8b},[x0],x8
add x20, x2, #8
csel x2, x20, x2,le
ld1 {v3.8b},[x10],x8
ld1 {v4.8b},[x0],x8
sub x20, x6, x14
csel x2, x20, x2,le
ld1 {v5.8b},[x10],x8
subs x12,x12,#8
ld1 {v6.8b},[x0],x8
mov x6, x2
ld1 {v7.8b},[x10],x8
add x20, x0, x4
csel x0, x20, x0,le
rev64 v16.8b, v0.8b
add x7, x6, x3
rev64 v17.8b, v1.8b
sub x20, x0, #8
csel x0, x20, x0,le
rev64 v18.8b, v2.8b
csel x12, x4, x12,le
rev64 v19.8b, v3.8b
add x9, x7, x3
rev64 v20.8b, v4.8b
add x10,x0,#-1
rev64 v21.8b, v5.8b
subs x1, x1, #8
rev64 v22.8b, v6.8b
add x14, x9, x3
rev64 v23.8b, v7.8b
bne kernel_mode2
epilogue_mode2:
st1 {v16.8b},[x6],x5
st1 {v17.8b},[x7],x5
st1 {v18.8b},[x9],x5
st1 {v19.8b},[x14],x5
st1 {v20.8b},[x6],x5
st1 {v21.8b},[x7],x5
st1 {v22.8b},[x9],x5
st1 {v23.8b},[x14],x5
b end_func
mode2_4:
mov x8,#-2
sub x0,x0,#1
add x10,x0,#-1
ld1 {v0.8b},[x0],x8
add x5,x2,x3
ld1 {v2.8b},[x10],x8
add x6,x5,x3
ld1 {v4.8b},[x0]
add x7,x6,x3
ld1 {v6.8b},[x10]
rev64 v1.8b, v0.8b
rev64 v3.8b, v2.8b
st1 {v1.s}[0],[x2]
rev64 v5.8b, v4.8b
st1 {v3.s}[0],[x5]
rev64 v7.8b, v6.8b
st1 {v5.s}[0],[x6]
st1 {v7.s}[0],[x7]
end_func:
// ldmfd sp!,{x4-x12,x15} //reload the registers from sp
ldp x19, x20,[sp],#16
ret
|
